ESP8266, Control Relay dengan Telegram

Hello Sahabat Anak Kendali.

Pada kesempatan kali ini saya akan membahas bagaimana Cara Mengontrol Led dengan Telegram ESP8266 Wemos D1.
Lihat Juga : Tutorial Telgram dengan ESP-01
disini modul yang saya gunakan adalah tipe ESP8266 Wemos D1 mini. untuk project ini bisa dikembangkan untuk smart home seperti Mengontrol Relay, Mengontrol peralatan rumah, dengan menggunakan aplikasi android telegram ini kita dapat mengontrol perlatan rumah jarak jauh, dan yang dibutuhkan adalah koneksi internet.

baiklah langsung saja berikut langkah Cara Mengontrol Led dengan Telegram ESP8266 Wemos D1.
1. Membuat akun bot di telegram
untuk lebih jelasnya silahkan buka telegram dan ikuti Skirinsut dibawah ini

setelah itu silahkan download library nya dibawah ini
https://github.com/witnessmenow/Universal-Arduino-Telegram-Bot
silahkan buka example nya universaltelegram bot >> esp8266 >> flash led

kemudian isikan program untuk menghubungkan ke jaringan wifi berupa nama wifi dan passwordnya.

kemudian isi BOtoken nya sesuai bot yang kita buat tadi di telegram.

dan uplod program nya, selesai !

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>
// Initialize Wifi connection to the router
char ssid[] = "XXXXXX";     // your network SSID (name)
char password[] = "YYYYYY"; // your network key
// Initialize Telegram BOT
#define BOTtoken "XXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"  // your Bot Token (Get from Botfather)
WiFiClientSecure client;
UniversalTelegramBot bot(BOTtoken, client);
int Bot_mtbs = 1000; //mean time between scan messages
long Bot_lasttime;   //last time messages' scan has been done
bool Start = false;
const int ledPin = 13;
int ledStatus = 0;
void handleNewMessages(int numNewMessages) {
  Serial.println("handleNewMessages");
  Serial.println(String(numNewMessages));
  for (int i=0; i<numNewMessages; i++) {
    String chat_id = String(bot.messages[i].chat_id);
    String text = bot.messages[i].text;
    String from_name = bot.messages[i].from_name;
    if (from_name == "") from_name = "Guest";
    if (text == "/ledon") {
      digitalWrite(ledPin, HIGH);   // turn the LED on (HIGH is the voltage level)
      ledStatus = 1;
      bot.sendMessage(chat_id, "Led is ON", "");
    }
    if (text == "/ledoff") {
      ledStatus = 0;
      digitalWrite(ledPin, LOW);    // turn the LED off (LOW is the voltage level)
      bot.sendMessage(chat_id, "Led is OFF", "");
    }
    if (text == "/status") {
      if(ledStatus){
        bot.sendMessage(chat_id, "Led is ON", "");
      } else {
        bot.sendMessage(chat_id, "Led is OFF", "");
      }
    }
    if (text == "/start") {
      String welcome = "Welcome to Universal Arduino Telegram Bot library, " + from_name + ".n";
      welcome += "This is Flash Led Bot example.nn";
      welcome += "/ledon : to switch the Led ONn";
      welcome += "/ledoff : to switch the Led OFFn";
      welcome += "/status : Returns current status of LEDn";
      bot.sendMessage(chat_id, welcome, "Markdown");
    }
  }
}

void setup() {
  Serial.begin(115200);
  // Set WiFi to station mode and disconnect from an AP if it was Previously
  // connected
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  delay(100);
  // attempt to connect to Wifi network:
  Serial.print("Connecting Wifi: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  pinMode(ledPin, OUTPUT); // initialize digital ledPin as an output.
  delay(10);
  digitalWrite(ledPin, LOW); // initialize pin as off
}
void loop() {
  if (millis() > Bot_lasttime + Bot_mtbs)  {
    int numNewMessages = bot.getUpdates(bot.last_message_received + 1);
    while(numNewMessages) {
      Serial.println("got response");
      handleNewMessages(numNewMessages);
      numNewMessages = bot.getUpdates(bot.last_message_received + 1);
    }
    Bot_lasttime = millis();
  }
}