By | 20/05/2020
1 Comment

Helo temen temen anakkendali.com
Pada kesempatan kali ini saya akan menulis artikel tentang Tutorial Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos, Jika menggunakan board arduino bisa mengaksesnya dengan library U8glib.h, namun library ini tidak support dengan NodeMCU atau Wemos untuk mengakses lcd Oled 0.96. Pada tutorial ini kita akan mengakses lcd oled 0.96 SSD1306 dengan library Adafruit_SSD1306.h oled. SSD1306 Oled 0.96 ESP8266

LCD Oled 0.96 terdapat dua jenis ukuran grafik tampilan. yang pertama ukuran garfiknya 128×32 dan yang kedua ukuran grafiknya adalah 128×64. Kedua ukuran grafik ini dapat diakses menggunakan satu library Adafruit_SSD1306.h oled sehingga kita tidak perlu menginstal library lainya. Adapun komunikasi yang digunakan untuk dapat mengakses modul lcd oled 0.96 dengan NodeMCU adalah I2C. Namun sebenarnya lcd oled ini banyak sekali tipe nya dan ada juga yang menggunakan komunikasi SPI.

Jika kalian mempunya modul LCD oled dengan spesifikasi pin sebagai berikut, itu tandanya modul lcd oled kalian menggunakan komunikasi I2C. SSD1306 Oled 0.96 ESP8266

Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos I2C
  • VCC
  • GND
  • SCL
  • SDA

sedangkan jika kalian mempunyai lcd oled dengan spesifikasi pin sebagai berikut, itu tandanya modul lcd oled kalian menggunakan komunikasi SPI.

  • GND
  • VCC
  • DO (Mosi)
  • DI (Miso)
  • CLK
  • DC
  • CS

Install Library Adafruit_SSD1306.h

Silahkan download library Adafruit_SSD1306.h dari link github yang sudah diberikan kemudian buka software arduino IDE, klik Sketch > Include Library > Add Library .zip atau bisa ikuti langkah berikut untuk menginstal library melalui Arduino IDE.

Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos
Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos

Selain library Adafruit_SSD1306.h diperlukan library lainya sebagai pendukung supaya esp8266 nodemcu atau wemos dapat mengakses modul lcd oled 0.96. library yang dibutuhkan yaitu Adafruit_GFX.h. Silahkan install library GFX versi terbarunya. jika kalian sudah menginstall sebelumnya maka kalian perlu meng upgrade versi library gfx.

Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos

Test Oled 0.96 Wemos D1 mini

Sekarang kita akan coba program untuk test tampilan grafik lcd oled 0.96 dengan modul wemos d1 mini, copy paste program berikut atau bisa buka example dan pilih “ssd1306_128x32_i2c”.


#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16
static const unsigned char PROGMEM logo_bmp[] =
{ B00000000, B11000000,
  B00000001, B11000000,
  B00000001, B11000000,
  B00000011, B11100000,
  B11110011, B11100000,
  B11111110, B11111000,
  B01111110, B11111111,
  B00110011, B10011111,
  B00011111, B11111100,
  B00001101, B01110000,
  B00011011, B10100000,
  B00111111, B11100000,
  B00111111, B11110000,
  B01111100, B11110000,
  B01110000, B01110000,
  B00000000, B00110000 };

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  display.display();
  delay(2000); // Pause for 2 seconds

  // Clear the buffer
  display.clearDisplay();

  // Draw a single pixel in white
  display.drawPixel(10, 10, SSD1306_WHITE);

  // Show the display buffer on the screen. You MUST call display() after
  // drawing commands to make them visible on screen!
  display.display();
  delay(2000);
  // display.display() is NOT necessary after every single drawing command,
  // unless that's what you want...rather, you can batch up a bunch of
  // drawing operations and then update the screen all at once by calling
  // display.display(). These examples demonstrate both approaches...

  testdrawline();      // Draw many lines

  testdrawrect();      // Draw rectangles (outlines)

  testfillrect();      // Draw rectangles (filled)

  testdrawcircle();    // Draw circles (outlines)

  testfillcircle();    // Draw circles (filled)

  testdrawroundrect(); // Draw rounded rectangles (outlines)

  testfillroundrect(); // Draw rounded rectangles (filled)

  testdrawtriangle();  // Draw triangles (outlines)

  testfilltriangle();  // Draw triangles (filled)

  testdrawchar();      // Draw characters of the default font

  testdrawstyles();    // Draw 'stylized' characters

  testscrolltext();    // Draw scrolling text

  testdrawbitmap();    // Draw a small bitmap image

  // Invert and restore display, pausing in-between
  display.invertDisplay(true);
  delay(1000);
  display.invertDisplay(false);
  delay(1000);

  testanimate(logo_bmp, LOGO_WIDTH, LOGO_HEIGHT); // Animate bitmaps
}

void loop() {
}

void testdrawline() {
  int16_t i;

  display.clearDisplay(); // Clear display buffer

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, 0, i, display.height()-1, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn line
    delay(1);
  }
  for(i=0; i<display.height(); i+=4) {
    display.drawLine(0, 0, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(0, display.height()-1, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=display.width()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.height(); i+=4) {
    display.drawLine(display.width()-1, 0, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=0; i<display.width(); i+=4) {
    display.drawLine(display.width()-1, 0, i, display.height()-1, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000); // Pause for 2 seconds
}

void testdrawrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=2) {
    display.drawRect(i, i, display.width()-2*i, display.height()-2*i, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testfillrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=3) {
    // The INVERSE color is used so rectangles alternate white/black
    display.fillRect(i, i, display.width()-i*2, display.height()-i*2, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testdrawcircle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=2) {
    display.drawCircle(display.width()/2, display.height()/2, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillcircle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=3) {
    // The INVERSE color is used so circles alternate white/black
    display.fillCircle(display.width() / 2, display.height() / 2, i, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn circle
    delay(1);
  }

  delay(2000);
}

void testdrawroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    // The INVERSE color is used so round-rects alternate white/black
    display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawtriangle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=5) {
    display.drawTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfilltriangle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=5) {
    // The INVERSE color is used so triangles alternate white/black
    display.fillTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawchar(void) {
  display.clearDisplay();

  display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE); // Draw white text
  display.setCursor(0, 0);     // Start at top-left corner
  display.cp437(true);         // Use full 256 char 'Code Page 437' font

  // Not all the characters will fit on the display. This is normal.
  // Library will draw what it can and the rest will be clipped.
  for(int16_t i=0; i<256; i++) {
    if(i == '\n') display.write(' ');
    else          display.write(i);
  }

  display.display();
  delay(2000);
}

void testdrawstyles(void) {
  display.clearDisplay();

  display.setTextSize(1);             // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);        // Draw white text
  display.setCursor(0,0);             // Start at top-left corner
  display.println(F("Hello, world!"));

  display.setTextColor(SSD1306_BLACK, SSD1306_WHITE); // Draw 'inverse' text
  display.println(3.141592);

  display.setTextSize(2);             // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.print(F("0x")); display.println(0xDEADBEEF, HEX);

  display.display();
  delay(2000);
}

void testscrolltext(void) {
  display.clearDisplay();

  display.setTextSize(2); // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(10, 0);
  display.println(F("scroll"));
  display.display();      // Show initial text
  delay(100);

  // Scroll in various directions, pausing in-between:
  display.startscrollright(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrollleft(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrolldiagright(0x00, 0x07);
  delay(2000);
  display.startscrolldiagleft(0x00, 0x07);
  delay(2000);
  display.stopscroll();
  delay(1000);
}

void testdrawbitmap(void) {
  display.clearDisplay();

  display.drawBitmap(
    (display.width()  - LOGO_WIDTH ) / 2,
    (display.height() - LOGO_HEIGHT) / 2,
    logo_bmp, LOGO_WIDTH, LOGO_HEIGHT, 1);
  display.display();
  delay(1000);
}

#define XPOS   0 // Indexes into the 'icons' array in function below
#define YPOS   1
#define DELTAY 2

void testanimate(const uint8_t *bitmap, uint8_t w, uint8_t h) {
  int8_t f, icons[NUMFLAKES][3];

  // Initialize 'snowflake' positions
  for(f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
    icons[f][YPOS]   = -LOGO_HEIGHT;
    icons[f][DELTAY] = random(1, 6);
    Serial.print(F("x: "));
    Serial.print(icons[f][XPOS], DEC);
    Serial.print(F(" y: "));
    Serial.print(icons[f][YPOS], DEC);
    Serial.print(F(" dy: "));
    Serial.println(icons[f][DELTAY], DEC);
  }

  for(;;) { // Loop forever...
    display.clearDisplay(); // Clear the display buffer

    // Draw each snowflake:
    for(f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], bitmap, w, h, SSD1306_WHITE);
    }

    display.display(); // Show the display buffer on the screen
    delay(200);        // Pause for 1/10 second

    // Then update coordinates of each flake...
    for(f=0; f< NUMFLAKES; f++) {
      icons[f][YPOS] += icons[f][DELTAY];
      // If snowflake is off the bottom of the screen...
      if (icons[f][YPOS] >= display.height()) {
        // Reinitialize to a random position, just off the top
        icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
        icons[f][YPOS]   = -LOGO_HEIGHT;
        icons[f][DELTAY] = random(1, 6);
      }
    }
  }
}

Perhatikan pada bagian syntax berikut yang terdapat pada kode diatas

#define OLED_RESET -1

Syntax bawaan librarynya dari contoh “ssd1306_128x32_i2c” adalah #define OLED_RESET 4, tapi silahkan rubah ke -1 supaya kode dari library Adafruit_SSD1306.h dapat berjalan pada modul esp8266 seperti wemos d1 mini atau nodemcu karena jika dibiarkan 4 maka pin SDA nodemcu akan terganggu.

Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos oled 0.96

Menampilkan Teks LCD OLED 0.96 Wemos D1 Mini

Selanjutnya kita akan menampilkan contoh teks pada lcd oled 0.96 yang memiliki grafik ukuran 128×32, jadi tidak boleh menentukan kursor x lebih dari 128 dan kursor y lebih dari 32.


#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for (;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  delay(2000);
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(10, 1);
  display.println("www.anakkendali.com");
  display.setCursor(20, 10);
  display.println("Grow Up Your");
  display.setCursor(10, 20);
  display.println("Programming Skill!!");
  display.display();
}

void loop() {
}

Merubah Font LCD Oled 0.96

Kalian dapat merubah jenis font pada tampilan lcd oled dengan pilihan font sebagai berikut :

FreeMono12pt7b.h		FreeSansBoldOblique12pt7b.h
FreeMono18pt7b.h		FreeSansBoldOblique18pt7b.h
FreeMono24pt7b.h		FreeSansBoldOblique24pt7b.h
FreeMono9pt7b.h			FreeSansBoldOblique9pt7b.h
FreeMonoBold12pt7b.h		FreeSansOblique12pt7b.h
FreeMonoBold18pt7b.h		FreeSansOblique18pt7b.h
FreeMonoBold24pt7b.h		FreeSansOblique24pt7b.h
FreeMonoBold9pt7b.h		FreeSansOblique9pt7b.h
FreeMonoBoldOblique12pt7b.h	FreeSerif12pt7b.h
FreeMonoBoldOblique18pt7b.h	FreeSerif18pt7b.h
FreeMonoBoldOblique24pt7b.h	FreeSerif24pt7b.h
FreeMonoBoldOblique9pt7b.h	FreeSerif9pt7b.h
FreeMonoOblique12pt7b.h		FreeSerifBold12pt7b.h
FreeMonoOblique18pt7b.h		FreeSerifBold18pt7b.h
FreeMonoOblique24pt7b.h		FreeSerifBold24pt7b.h
FreeMonoOblique9pt7b.h		FreeSerifBold9pt7b.h
FreeSans12pt7b.h		FreeSerifBoldItalic12pt7b.h
FreeSans18pt7b.h		FreeSerifBoldItalic18pt7b.h
FreeSans24pt7b.h		FreeSerifBoldItalic24pt7b.h
FreeSans9pt7b.h			FreeSerifBoldItalic9pt7b.h
FreeSansBold12pt7b.h		FreeSerifItalic12pt7b.h
FreeSansBold18pt7b.h		FreeSerifItalic18pt7b.h
FreeSansBold24pt7b.h		FreeSerifItalic24pt7b.h
FreeSansBold9pt7b.h		FreeSerifItalic9pt7b.h

Cara merubah font oled 0.96

Cara merubah font oled 0.96 dengan library adafruit_gfx.h seperti langkah berikut ini :

  • masukan library font yang ingin digunakan
    misalkan saya ingin menggunakan library font FreeSerif9pt7b.h contohnya #include <FreeSerif9pt7b.h>
  • panggil fungsi untuk menerapkan font pada teks yang akan di tampilkan
    display.setFont(&FreeSerif9pt7b);

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Fonts/FreeSerif9pt7b.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for (;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  delay(2000);
  display.clearDisplay();
  display.setFont(&FreeSerif9pt7b);
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 10);
  display.println("anakkendali.com");
  display.display();
}

void loop() {
}
Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos oled 0.96

Bitmap Oled 0.96 NodeMCU/Wemos D1 Mini

Selanjutnya kita akan menampilkan gambar dalam format bitmap pada lcd oled 0.96 dengan ukuran grafik 128×32. langsung saja ikuti langkah-langkahnya sebagai berikut.

  • Siapkan gambar logo dalam bentu png/jpg
  • kunjungi link berikut untuk mengkonversi gambar ke bitmap dan mendapatkan kode biner atau hexa nya. https://www.skaarhoj.com/FreeStuff/GraphicDisplayImageConverter.php
  • Sesuaikan ukuran yang di inginkan, ingat jangan lebih dari maksimal grafik modul lcd oled 0.96 yang kamu miliki.
  • copy paste kode biner hasil konversi ke dalam program berikut.

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Fonts/FreeSerif9pt7b.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   32
#define LOGO_WIDTH    64
static const unsigned char PROGMEM logo_anakkendali[] =
{ B00000000, B00000000, B00000000, B11111111, B11111111, B00000000, B00000000, B00000000, 
  B00000000, B00000000, B00011111, B11111111, B11111111, B11111000, B00000000, B00000000, 
  B00000000, B00000001, B11111111, B11111111, B11111111, B11111111, B10000000, B00000000, 
  B00000000, B00001111, B11111111, B11111111, B11111111, B11111111, B11110000, B00000000, 
  B00000000, B00111111, B11111111, B10000000, B00111111, B11111111, B11111100, B00000000, 
  B00000000, B11111111, B11111000, B00000000, B00011111, B11111111, B11111111, B00000000, 
  B00000011, B11111111, B11000000, B00000000, B00011111, B11111111, B11111111, B11000000, 
  B00000111, B11111111, B10000000, B01111000, B00011111, B11111111, B11111111, B11100000, 
  B00001111, B11111110, B00000011, B11111000, B00011111, B11111111, B11111111, B11110000, 
  B00011111, B11111100, B00001111, B11111000, B00011111, B11111111, B11111111, B11111000, 
  B00111111, B11111000, B00011111, B11111000, B00011111, B11111111, B11111111, B11111100, 
  B01111111, B11110000, B00111111, B11111000, B00011111, B11111111, B11111111, B11111110, 
  B01111111, B11100000, B00111111, B11111000, B00011111, B11111111, B11111111, B11111110, 
  B11111100, B00000000, B00111111, B11111000, B00011111, B11111111, B11111111, B11111111, 
  B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, 
  B11111111, B11111111, B01110111, B11111111, B11111111, B11111111, B11111111, B11111111, 
  B11111111, B11110111, B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, 
  B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, B11111111, 
  B11111111, B11111111, B11111111, B11111000, B00011111, B11111100, B00000000, B00111111, 
  B01111111, B11111111, B11111111, B11111000, B00011111, B11111100, B00000111, B11111110, 
  B01111111, B11111111, B11111111, B11111000, B00011111, B11111100, B00001111, B11111110, 
  B00111111, B11111111, B11111111, B11111000, B00011111, B11111000, B00011111, B11111100, 
  B00011111, B11111111, B11111111, B11111000, B00011111, B11110000, B00111111, B11111000, 
  B00001111, B11111111, B11111111, B11111000, B00011111, B11000000, B01111111, B11110000, 
  B00000111, B11111111, B11111111, B11111000, B00011111, B00000000, B11111111, B11100000, 
  B00000011, B11111111, B11111111, B11111000, B00000000, B00000011, B11111111, B11000000, 
  B00000000, B11111111, B11111111, B11111000, B00000000, B00001111, B11111111, B00000000, 
  B00000000, B00111111, B11111111, B11111100, B00000000, B11111111, B11111100, B00000000, 
  B00000000, B00001111, B11111111, B11111111, B11111111, B11111111, B11110000, B00000000, 
  B00000000, B00000001, B11111111, B11111111, B11111111, B11111111, B10000000, B00000000, 
  B00000000, B00000000, B00011111, B11111111, B11111111, B11111000, B00000000, B00000000, 
  B00000000, B00000000, B00000000, B11111111, B11111111, B00000000, B00000000, B00000000,  
};

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for (;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  delay(2000);
  display.clearDisplay();
  display.setFont(&FreeSerif9pt7b);
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 10);
  display.println("anakkendali.com");
  display.display();
  delay(2000);
  display.clearDisplay();
  testdrawbitmap();
  delay(3000);
  testanimate(logo_anakkendali, LOGO_WIDTH, LOGO_HEIGHT);
}

void loop() {
}
void testdrawbitmap(void) {
  display.clearDisplay();

  display.drawBitmap(
    (display.width()  - LOGO_WIDTH ) / 2,
    (display.height() - LOGO_HEIGHT) / 2,
    logo_anakkendali, LOGO_WIDTH, LOGO_HEIGHT, 1);
  display.display();
  delay(1000);
}

#define XPOS   0 
#define YPOS   1
#define DELTAY 2
void testanimate(const uint8_t *bitmap, uint8_t w, uint8_t h) {
  int8_t f, icons[NUMFLAKES][3];

  // Initialize 'snowflake' positions
  for(f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
    icons[f][YPOS]   = -LOGO_HEIGHT;
    icons[f][DELTAY] = random(1, 6);
    Serial.print(F("x: "));
    Serial.print(icons[f][XPOS], DEC);
    Serial.print(F(" y: "));
    Serial.print(icons[f][YPOS], DEC);
    Serial.print(F(" dy: "));
    Serial.println(icons[f][DELTAY], DEC);
  }

  for(;;) { // Loop forever...
    display.clearDisplay(); // Clear the display buffer

    // Draw each snowflake:
    for(f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], bitmap, w, h, SSD1306_WHITE);
    }

    display.display(); // Show the display buffer on the screen
    delay(200);        // Pause for 1/10 second

    // Then update coordinates of each flake...
    for(f=0; f< NUMFLAKES; f++) {
      icons[f][YPOS] += icons[f][DELTAY];
      // If snowflake is off the bottom of the screen...
      if (icons[f][YPOS] >= display.height()) {
        // Reinitialize to a random position, just off the top
        icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
        icons[f][YPOS]   = -LOGO_HEIGHT;
        icons[f][DELTAY] = random(1, 6);
      }
    }
  }
}

Baiklah mungkin cukup sekian apa yang bisa saya bagikan kali ini semoga bermanfaat. Itulah tutorial cara mudah mengakses lcd oled dengan nodemcu ataupun dengan wemos d1 mini. sampai ketemu di tutorial selanjutnya dan jangan lupa untuk membagikan ke akun sosial media kalian.

Pencarian terkait

One Reply to “Mudah Mengakses Oled 0.96 Adafruit_SSD1306.h NodeMCU/Wemos”

Leave a Reply

Your email address will not be published. Required fields are marked *